esse est percipi
Das Weblog eines Grafikdesigners. Seit 2003.

esse est percipi

Einfach gute Mac-Apps.

Von einem unabhängigen Entwickler,
der sie täglich selbst nutzt.

Blog Apps

Impressum/Datenschutz/AGB

Digitale Welt | Dienstag, 14. Januar 2014

Mac OS X: E-Mail zu Erinnerungen hinzufügen

Es kommt ab und zu vor, dass ich nicht sofort auf eine E-Mail reagieren kann – sei es, weil ich vorher erst noch was klären muss oder auch einfach nur, weil ich gerade keine Zeit habe. Damit ich die Mail nicht vergesse, markiere ich sie mit einer Flagge – und vergesse sie dann oft genug trotzdem.

Mit diesem kleinen Applescript erzeugt man einen neuen „Erinnerungen“-Eintrag mit dem Betreff der gerade aktiven E-Mail, der am folgenden Morgen um 9 Uhr noch mal an selbige erinnert:

tell application "Mail"
	set _selection to selection
	set _message to item 1 of _selection
	set _from to (sender of _message as string)
	set _subject to (subject of _message as string)
	set _body to content of _message
	set _body to paragraph 1 of _body & return & paragraph 2 of _body & return & paragraph 3 of _body
	set _ID to message id of _message
	set _URL to "message://%3c" & _ID & "%3e"
	set _alarm to ((current date) + 1 * days)
	set time of _alarm to 60 * 60 * 9
end tell

tell application "Reminders"
	make new reminder with properties {name:_subject, body:"Von: " & _from & return & _body & return & _URL, remind me date:_alarm}
end tell

Im Notiz-Feld der Erinnerung befindet sich neben den drei ersten Absätzen der Mail auch ein Link, der einen direkt zur betreffenden Mail in Mail.app befördert, damit man sofort tätig werden kann:

~~Die einzige Einschränkung: Der Link zur E-Mail funktioniert auf iOS-Geräten nicht.~~

Kommentare:

Bei den Kommentaren handelt es sich um fremde Inhalte, die sich „esse est percipi“ nicht zueigen macht. Verantwortlich für den Inhalt eines Kommentars ist der jeweilige Verfasser.

Patrick Mittwoch, 15. Januar 2014, 14:35 Uhr

Kann man auch ein Dialogfeld einrichten, in dem man das Datum und die Erinnerung der Mail eingeben kann? Das wäre dann perfekt!

Michael Preidel Donnerstag, 16. Januar 2014, 10:51 Uhr

Gute Idee. Setze ich nachher mal um und mache dann ein Update.

Die Einschränkung mit iOS-Geräten gilt übrigens nicht mehr, unter iOS 7 funktionieren die „message“-Links einwandfrei.

Rene Montag, 24. Februar 2014, 16:28 Uhr

Hallo,

super Idee vorab!

Leider kommt bei mir folgender Fehler:
error „„item 1 of {}“ kann nicht gelesen werden.“ number -1728 from item 1 of {}

Was mache ich falsch?

Michael Preidel Montag, 24. Februar 2014, 18:08 Uhr

Diese Fehlermeldung erscheint, wenn in Mail keine Nachricht ausgewählt ist. Hier eine Version des Scripts, die den Fehler abfängt und den User informiert, dass eine Nachricht ausgewählt werden muss:

tell application "Mail"
	try
		set _selection to selection
		set _message to item 1 of _selection
		set _from to (sender of _message as string)
		set _subject to (subject of _message as string)
		set _body to content of _message
		set _body to paragraph 1 of _body & return & paragraph 2 of _body & return & paragraph 3 of _body
		set _ID to message id of _message
		set _URL to "message://%3c" & _ID & "%3e"
		set _alarm to ((current date) + 1 * days)
		set time of _alarm to 60 * 60 * 9
	on error
		display dialog "Bitte wählen Sie zuerst eine Nachricht aus." buttons {"Ok"} default button 1 with icon 0
	end try
end tell

tell application "Reminders"
	try
		make new reminder with properties {name:_subject, body:"Von: " & _from & return & _body & return & _URL, remind me date:_alarm}
	end try
end tell